X9

The HUD class (CustomHUD.uc)

Our hud is the same as the one here. Just make sure you check the link if you need more explanations, so I will just give you the code with the difference that the HUD class extends from UTHUD and that a DrawHUD is already in the base class so if you want to add drawing routines like the mouse cursor, you can do so by declaring a new function.

var bool bDrawTraces; //Hold exec console function switch to display debug of trace lines & Paths.

var const Texture2D CursorTexture;

exec function ToggleIsometricDebug()
{
        bDrawTraces = !bDrawTraces;
        if(bDrawTraces)
        {
                `Log("Showing debug line trace for mouse");
        }
        else
        {
                `Log("Disabling debug line trace for mouse");
        }
}

function DrawTraceDebugRays()
{
        local CustomPlayerController PlayerController;
        PlayerController = CustomPlayerController(PlayerOwner);

        //Draw Trace from the camera to the world using
        Draw3DLine(PlayerController.StartTrace, PlayerController.EndTrace, MakeColor(255,128,128,255));
}

function vector2D GetMouseCoordinates()
{
        local Vector2D mousePos;
        local UIInteraction UIController;
        local GameUISceneClient GameSceneClient;

        UIController  = PlayerOwner.GetUIController();

        if ( UIController != None)
        {
                GameSceneClient = UIController.SceneClient;
                if ( GameSceneClient != None )
                {
                        mousePos.X = GameSceneClient.MousePosition.X;
                        mousePos.Y = GameSceneClient.MousePosition.Y;
                }
        }

        return mousePos;
}

event PostRender()
{
        local CustomCamera PlayerCam;
        local CustomPlayerController PlayerController;

        super.PostRender();

        //Get a type casted reference to our custom player controller.
        PlayerController = CustomPlayerController(PlayerOwner);

        //Get the mouse coordinates from the GameUISceneClient
        PlayerController.PlayerMouse = GetMouseCoordinates();
        //Deproject the 2d mouse coordinate into 3d world. Store the MousePosWorldLocation and normal (direction).
        Canvas.DeProject(PlayerController.PlayerMouse, PlayerController.MousePosWorldLocation, PlayerController.MousePosWorldNormal);

        //Get a type casted reference to our custom camera.
        PlayerCam = CustomCamera(PlayerController.PlayerCamera);

        //Calculate a trace from Player camera + 100 up(z) in direction of deprojected MousePosWorldNormal (the direction of the mouse).
        //-----------------
        //Set the ray direction as the mouseWorldnormal
        PlayerController.RayDir = PlayerController.MousePosWorldNormal;
        //Start the trace at the player camera (isometric) + 100 unit z and a little offset in front of the camera (direction *10)
        PlayerController.StartTrace = (PlayerCam.ViewTarget.POV.Location + vect(0,0,100)) + PlayerController.RayDir * 10;
        //End this ray at start + the direction multiplied by given distance (5000 unit is far enough generally)
        PlayerController.EndTrace = PlayerController.StartTrace + PlayerController.RayDir * 5000;

        //Trace MouseHitWorldLocation each frame to world location (here you can get from the trace the actors that are hit by the trace, for the sake of this
        //simple tutorial, we do noting with the result, but if you would filter clicks only on terrain, or if the player clicks on an npc, you would want to inspect
        //the object hit in the StartFire function
        PlayerController.TraceActor = Trace(PlayerController.MouseHitWorldLocation, PlayerController.MouseHitWorldNormal, PlayerController.EndTrace, PlayerController.StartTrace, true);

        //Calculate the pawn eye location for debug ray and for checking obstacles on click.
        PlayerController.PawnEyeLocation = Pawn(PlayerOwner.ViewTarget).Location + Pawn(PlayerOwner.ViewTarget).EyeHeight * vect(0,0,1);

        //Your basic draw hud routine
        DrawHUD();

		//CustomCursorDrawing
		DrawCustomCursor();

	if(bDrawTraces)
		DrawTraceDebugRays();
}

function DrawCustomCursor()
{
	local vector2D mouseCoords;
	mouseCoords = GetMouseCoordinates();
	Canvas.SetPos(mouseCoords.X, mouseCoords.Y);
	Canvas.SetDrawColor(255,255,255,255);
	Canvas.DrawTile(CursorTexture, 32, 32, 0, 0, 128, 128);
}

DefaultProperties
{
	//Use a target for mouse cursor.
	CursorTexture=Texture2D'EditorMaterials.TargetIcon'
}

Pretty self explanatory here so we move on to the new link gun and then we will be able to compile and execute. It might be a good thing to check if your code compile without major errors, it should say that you are missing the link gun class specified in the Game Info class.

The LinkGun class (CustomLinkGun.uc)

This file is rather long and was modified by Yorg Kuijs directly so you could always ask him in the forum, his nickname is DuckSauce from the source files

Download the source for the entire tutorial